final: final-py: prev-py: {
  nestml = let
    pname = "nestml";
    # Newer versions require newer antlr4
    version = "7.0.2";
  in final-py.buildPythonPackage {
    inherit pname version;

    src = final.fetchFromGitHub {
      owner = "nest";
      repo = pname;
      rev = "v${version}";
      hash = "sha256-BQzwIh2Gdq+rLwIwe7dyltDfEzpaIWGlXF0AfZGBUDw=";
    };

    doCheck = false;
    dontUseCmakeConfigure = true;
    
    propagatedBuildInputs = with final-py; [
      numpy
      scipy
      sympy
      antlr4-python3-runtime
      #setuptools
      jinja2
      astropy
      semver
      odetoolbox
    ];
  };
  
  odetoolbox = let
    pname = "ode-toolbox";
    version = "2.5.8";
  in final-py.buildPythonPackage {
    inherit pname version;

    src = final.fetchFromGitHub {
      owner = "nest";
      repo = pname;
      rev = "v${version}";
      hash = "sha256-do/R9tNXVdeoqQO5ofetP7jdq9VUq4UotO6LH3LL6jI=";
    };

    buildInputs = with final-py; [
      pytest
      pytest-runner
    ];    

    doCheck = false;
    
    propagatedBuildInputs = with final-py; [
      matplotlib
      graphviz
      sympy
      scipy
      numpy
      cython
    ];
  };

  pytest-runner = let
    pname = "pytest-runner";
    version = "6.0.0";
  in final-py.buildPythonPackage {
    inherit pname version;
    pyproject = true;

    src = final.fetchFromGitHub {
      owner = "pytest-dev";
      repo = pname;
      rev = "v${version}";
      leaveDotGit = true;
      hash = "sha256-cfUqEu3vN2i8jKZcTxId8Q/T/ld25qBeXY63g0eJnPs=";
    };

    nativeBuildInputs = [
      final.git
    ];
    
    propagatedBuildInputs = with final-py; [
      setuptools-scm
    ];
  };  

  mne-python = prev-py.mne-python.overridePythonAttrs (old: {
    pyproject = true;
    format = null;
    propagatedBuildInputs = old.propagatedBuildInputs ++ [
      final-py.setuptools-scm
    ];
  });

  edfio = let
    version = "0.4.1";
    pname = "edfio";
  in final-py.buildPythonPackage {
    inherit pname version;
    format = "pyproject";
    
    src = final.fetchFromGitHub {
      owner = "the-siesta-group";
      repo = pname;
      rev = "v${version}";
      hash = "sha256-+yb3Q/JximkVS6SOTFnjMYghbOi+UBbqW2Bs29eSonA=";
    };

    nativeBuildInputs = with final-py; [
      poetry-core
      poetry-dynamic-versioning
    ];
    
    propagatedBuildInputs = with final-py; [
      numpy
    ];
  };

  importRosbag = final-py.buildPythonPackage {
    pname = "importRosbag";
    version = "1.0.4.1";
    
    src = final.fetchFromGitHub {
      owner = "event-driven-robotics";
      repo = "importRosbag";
      rev = "71183fe375ec0f79512100db16c1a955b7aadf62";
      hash = "sha256-2ey+IGKqkvvHhEneoZlSx1g074/WKpWKZED04BVXkaM=";
    };

    propagatedBuildInputs = with final-py; [
      tqdm
      numpy
    ];
  };
  
  expelliarmus = final-py.buildPythonPackage {
    pname = "expelliarmus";
    version = "14-03-23";
    
    src = final.fetchFromGitHub {
      owner = "open-neuromorphic";
      repo = "expelliarmus";
      rev = "6ed9e41e4d289b45d5e2ca2526cff4ea276f3494";
      hash = "sha256-glW0W6OjTpWu+DKtGHBaJXBm7XMZSQYEaC2DjghQFho=";
    };

    buildInputs = with final-py; [
      pytest
    ];

    propagatedBuildInputs = with final-py; [
      numpy
    ];
  };
  
  pytorch-data = final-py.buildPythonPackage rec {
    pname = "pytorch-data";
    version = "0.7.1";

    src = final.fetchFromGitHub {
      owner = "pytorch";
      repo = "data";
      rev = "v${version}";
      hash = "sha256-yF3WHVOP1BIhGpitkQDy8dry4ZnEOh4+U6XTaG7mBv4=";
      fetchSubmodules = true;
    };

    doCheck = false;

    nativeBuildInputs = with final; [
      cmake
    ];

    dontUseCmakeConfigure = true;
    
    buildInputs = with final; [
      git
    ];

    propagatedBuildInputs = with final-py; [
      urllib3
      requests
      torch
    ];
  };

  tonic = final-py.buildPythonPackage rec {
    pname = "tonic";
    version = "1.5.0";
    env.PBR_VERSION = version;
    src = final.fetchFromGitHub {
      owner = "neuromorphs";
      repo = "tonic";
      rev = "v${version}";
      hash = "sha256-edwd/iJpwBXGw7CB7bD/ZVW/47pwrTOzD2lX5ULHiMY=";
    };

    propagatedBuildInputs = with final-py; [
      numpy
      h5py
      importRosbag
      scipy
      tqdm
      librosa
      pbr
      expelliarmus
      typing-extensions
      # Technically not required
      torch
      torchaudio
      pytorch-data
    ];
  };
} // (import ./spynnaker.nix final final-py prev-py) #// (import ./smoldyn.nix final final-py prev-py)